Sysquake Remote Live

Moyenne mobile

La figure ci-dessous illustre la moyenne mobile, qui a deux effets: un lissage des données et un retard.

Les données sont produites par un générateur de nombres pseudo-aléatoires, mais elles pourraient tout aussi bien être lues dans une base de données ou venir d'un flux de données en temps réel sur Internet.

Code source

Voici le code source qui figure dans le fichier sur le serveur. Si vous jetez un coup d'oeil au code source dans votre butineur, vous ne verrez que le code HTML généré par Sysquake Remote.

<?sqr
% initialisation
rng default;
t = 1995 + (0:7*360) / 360;
n = length(t);
x = 100 + cumsum(randn(1, n) + 0.03);
w = 60;

% formulaire interactif
use sqr;
format = 'Largeur de la fenêtre: %{6}n\n%{Annuler}R%{Mettre à jour}S';
names = {'w'};
s0 = struct('w',w);
s = processhtmlform(format, names, s0);
s.w = max(min(s.w, 720), 2);	% doit être compris entre 2 et 720
displayhtmlform(format, names, s, 'get');
w = s.w;

% figure
beginfigure('size', [440, 300]);
plotoption xygrid;
plot(t, x, 'h(00e000)');
plot(t(w:end), conv(x,ones(1,w)/w)(w:end-w+1), 'k');
legend(sprintf('indice (1995=100)\nmoyenne mobile sur %d jours',w), ...
       'h(00e000)k')
endfigure;
?>